//+------------------------------------------------------------------+
//|      DTosc 2.05 Multi RSI.mq4 
//|                                        mladen ; extended by Boxter|
// http://www.forex-tsd.com/manual-trading-systems-indicators/3580-elite-indicators-509.html#post447605
// with floating levels and arrows, alerts, divergence , MTF
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers 5
#property indicator_minimum -5
#property indicator_maximum 105
#property indicator_color1  DeepSkyBlue  
#property indicator_color2  DimGray
#property indicator_color3  PaleVioletRed
#property indicator_color4  DeepSkyBlue
#property indicator_color5  Red
#property indicator_width4  1
#property indicator_width5  1
#property indicator_style1  STYLE_DOT
#property indicator_style2  STYLE_DOT
#property indicator_style3  STYLE_DOT

extern string TimeFrame             = "Current time frame";
extern int    RSI_Period            = 14;
extern int    RSI_Mode              = 0;       // 0=RSI,1=Wilders RSI,2=RSX,3=Cuttler RSI
extern int    RSI_Price             = PRICE_CLOSE;
extern int    PeriodStoch           = 14;//8
extern int    PeriodSK              = 9;//5
extern int    PeriodSD              = 3;//5
extern int    MAMode                = 3;
extern double SmoothPeriod          = 5;
extern int    SmoothPhase           = 0;
extern bool   SmoothDouble          = true;
extern int    MinMaxPeriod          =  50; // for floating levels
extern double LevelUp               =  80;
extern double LevelDown             =  20;
extern bool   Interpolate               = true;

extern bool   ShowArrowsOn100_0     = false;
extern bool   divergenceVisible         = false;
extern bool   divergenceOnValuesVisible = true;
extern bool   divergenceOnChartVisible  = true;
extern color  divergenceBullishColor    = LimeGreen;
extern color  divergenceBearishColor    = OrangeRed;
extern string divergenceUniqueID        = "dtosc divergence1";

extern bool   ShowArrows            = false;
extern bool   ShowArrowsUp          = true;
extern bool   ShowArrowsDown        = true;
extern bool   UseSignalLineFor100_0 = false;
extern string arrowsIdentifier      = "dtosc arrows";
extern color  arrowsUpColor         = LimeGreen;
extern color  arrowsDnColor         = OrangeRed;
extern double arrowsUpGap           = 0.75;
extern double arrowsDownGap         = 0.75;

extern bool   alertsOn              = false;
extern bool   alertsOnCurrent       = true;
extern bool   alertsMessage         = true;
extern bool   alertsSound           = true;//false;
extern bool   alertsEmail           = false;

double SK[];
double SD[];
double StoRSI[];
double RSI[];
double trend[];
double levelUp[];
double levelMi[];
double levelDn[];

string IndicatorFileName;
int    timeFrame;
bool   returnBars;
bool   calculateValue;
string shortName;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int init(){
   IndicatorBuffers(8);
   SetIndexBuffer(0,levelUp);
   SetIndexBuffer(1,levelMi);
   SetIndexBuffer(2,levelDn);
   SetIndexBuffer(3,SK);
   SetIndexBuffer(4,SD);
   SetIndexBuffer(5,StoRSI);
   SetIndexBuffer(6,RSI);
   SetIndexBuffer(7,trend);

   IndicatorFileName = WindowExpertName();
   returnBars        = (TimeFrame == "returnBars"); if (returnBars)     return(0);
   calculateValue    = (TimeFrame=="calculateValue");
   if (calculateValue){
      int s = StringFind(divergenceUniqueID,":",0);
      shortName = divergenceUniqueID;
      divergenceUniqueID = StringSubstr(divergenceUniqueID,0,s);
      return(0);
   }            
   timeFrame = stringToTimeFrame(TimeFrame);   

//   shortName = divergenceUniqueID+": "+timeFrameToString(timeFrame)+" DTOSC ("+RSI_Period+","+PeriodStoch+","+PeriodSK+","+PeriodSD+")";
   shortName = divergenceUniqueID+": "+timeFrameToString(timeFrame)+" DTosc 2.05 Multi RSI, "+getRsiName(RSI_Mode)+" ("+RSI_Period+","+PeriodStoch+","+PeriodSK+","+PeriodSD+")";
   IndicatorShortName(shortName);
   return(0);
}

int deinit(){
   if (!calculateValue && ShowArrows) deleteArrows();
   int lookForLength = StringLen(divergenceUniqueID);
   for (int i=ObjectsTotal()-1; i>=0; i--) {
      string name = ObjectName(i);  if (StringSubstr(name,0,lookForLength) == divergenceUniqueID) ObjectDelete(name);
   }
   return(0);
}


//+-------------------------------------------------------------------------------------------------------------------+
//|                                                                                                                   |
//+-------------------------------------------------------------------------------------------------------------------+

int start(){
   int i,limit;
   int counted_bars = IndicatorCounted();
   if(counted_bars < 0) return(-1);
   if(counted_bars > 0) counted_bars--;
   limit=MathMin(Bars-counted_bars,Bars-1);
   
   if (returnBars) { levelUp[0] = limit; return(0); }
   if (calculateValue || timeFrame == Period()){
      for(i=limit; i>=0; i--){
 //        RSI[i] = iRSI(NULL,0,RSI_Period,PRICE_CLOSE,i);
         RSI[i] = iRsi(iMA(NULL,0,1,0,MODE_SMA,RSI_Price,i),RSI_Period,i,RSI_Mode);
         
         double LLV = RSI[ArrayMinimum(RSI,PeriodStoch,i)];
         double HHV = RSI[ArrayMaximum(RSI,PeriodStoch,i)];
         if ((HHV-LLV)!=0)
               StoRSI[i] = iDSmooth(100.0*((RSI[i] - LLV)/(HHV - LLV)),SmoothPeriod,SmoothPhase,i);
         else  StoRSI[i] = iDSmooth(0,SmoothPeriod,SmoothPhase,i);
      } 
        
      for(i=limit; i>=0; i--) SK[i]=iMAOnArray(StoRSI,0,PeriodSK,0,MAMode,i);
      //------floating levels
      for(i=limit; i>=0; i--){
         double hi = SK[ArrayMaximum(SK,MinMaxPeriod,i)];
         double lo = SK[ArrayMinimum(SK,MinMaxPeriod,i)];
         double rn = hi-lo;
               levelUp[i] = lo+rn*LevelUp  /100.0;
               levelDn[i] = lo+rn*LevelDown/100.0;
               levelMi[i] = (levelUp[i]+levelDn[i])/2.0;
         SD[i]=iMAOnArray(SK,0,PeriodSD,0,MAMode,i);
         trend[i] = trend[i+1];
         if (!ShowArrowsOn100_0){      
            if (SK[i]>SD[i]) trend[i] =  1;
            if (SK[i]<SD[i]) trend[i] = -1;
         }
         else{
            trend[i] = 0;
            if (UseSignalLineFor100_0){
               if (NormalizeDouble(SD[i],Digits) == 100) trend[i] = -1;
               if (NormalizeDouble(SD[i],Digits) ==   0) trend[i] =  1;
            }
            else{
               if (NormalizeDouble(SK[i],Digits) == 100) trend[i] = -1;
               if (NormalizeDouble(SK[i],Digits) ==   0) trend[i] =  1;
            }
         }
         if (!calculateValue) manageArrow(i);
         if (divergenceVisible){
           CatchBullishDivergence(SK,i);
           CatchBearishDivergence(SK,i);
         } 
      }         
      manageAlerts();
      return(0);      
   }
   
   //-------------MTF
   
   limit = MathMax(limit,MathMin(Bars-1,iCustom(NULL,timeFrame,IndicatorFileName,"returnBars",0,0)*timeFrame/Period()));
   for(i=limit; i>=0; i--){
      int y = iBarShift(NULL,timeFrame,Time[i]);
         levelUp[i] = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",RSI_Period,RSI_Mode,RSI_Price,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,Interpolate,0,y);
         levelMi[i] = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",RSI_Period,RSI_Mode,RSI_Price,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,Interpolate,1,y);
         levelDn[i] = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",RSI_Period,RSI_Mode,RSI_Price,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,Interpolate,2,y);
         SK[i]      = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",RSI_Period,RSI_Mode,RSI_Price,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,Interpolate,3,y);
         SD[i]      = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",RSI_Period,RSI_Mode,RSI_Price,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,Interpolate,4,y);
         trend[i]   = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",RSI_Period,RSI_Mode,RSI_Price,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,Interpolate,7,y);
         manageArrow(i);
      
         if (timeFrame <= Period() || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;
         if (!Interpolate) continue;

         datetime time = iTime(NULL,timeFrame,y);
            for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            for(int k = 1; k < n; k++)
            {
               SK[i+k] = SK[i] +(SK[i+n]-SK[i])*k/n;
               SD[i+k] = SD[i] +(SD[i+n]-SD[i])*k/n;
               levelUp[i+k] = levelUp[i] + (levelUp[i+n]-levelUp[i])*k/n;
               levelMi[i+k] = levelMi[i] + (levelMi[i+n]-levelMi[i])*k/n;
               levelDn[i+k] = levelDn[i] + (levelDn[i+n]-levelDn[i])*k/n;
            }               
   }                          
   manageAlerts();
   return(0);
}


//+------------------------------------------------------------------
//|  Divergeance
//+------------------------------------------------------------------

void CatchBullishDivergence(double& values[], int i){
   i++;
   ObjectDelete(divergenceUniqueID+"l"+DoubleToStr(Time[i],0));
   ObjectDelete(divergenceUniqueID+"l"+"os" + DoubleToStr(Time[i],0));            
   if (!IsIndicatorLow(values,i)) return;  
   int currentLow = i;
   int lastLow    = GetIndicatorLastLow(values,i+1);
   if (values[currentLow] > values[lastLow] && Low[currentLow] < Low[lastLow]){
         if(divergenceOnChartVisible)  DrawPriceTrendLine("l",Time[currentLow],Time[lastLow],Low[currentLow],Low[lastLow],divergenceBullishColor,STYLE_SOLID);
         if(divergenceOnValuesVisible) DrawIndicatorTrendLine("l",Time[currentLow],Time[lastLow],values[currentLow],values[lastLow],divergenceBullishColor,STYLE_SOLID);
   }
   if (values[currentLow] < values[lastLow] && Low[currentLow] > Low[lastLow]){
         if(divergenceOnChartVisible)  DrawPriceTrendLine("l",Time[currentLow],Time[lastLow],Low[currentLow],Low[lastLow], divergenceBullishColor, STYLE_DOT);
         if(divergenceOnValuesVisible) DrawIndicatorTrendLine("l",Time[currentLow],Time[lastLow],values[currentLow],values[lastLow], divergenceBullishColor, STYLE_DOT);
   }
}

void CatchBearishDivergence(double& values[], int i){
   i++; 
   ObjectDelete(divergenceUniqueID+"h"+DoubleToStr(Time[i],0));
   ObjectDelete(divergenceUniqueID+"h"+"os" + DoubleToStr(Time[i],0));            
   if (IsIndicatorPeak(values,i) == false) return;
      
   int currentPeak = i;
   int lastPeak = GetIndicatorLastPeak(values,i+1);
   if (values[currentPeak] < values[lastPeak] && High[currentPeak]>High[lastPeak]){
         if (divergenceOnChartVisible)  DrawPriceTrendLine("h",Time[currentPeak],Time[lastPeak],High[currentPeak],High[lastPeak],divergenceBearishColor,STYLE_SOLID);
         if (divergenceOnValuesVisible) DrawIndicatorTrendLine("h",Time[currentPeak],Time[lastPeak],values[currentPeak],values[lastPeak],divergenceBearishColor,STYLE_SOLID);
   }
   if(values[currentPeak] > values[lastPeak] && High[currentPeak] < High[lastPeak]){
         if (divergenceOnChartVisible)  DrawPriceTrendLine("h",Time[currentPeak],Time[lastPeak],High[currentPeak],High[lastPeak], divergenceBearishColor, STYLE_DOT);
         if (divergenceOnValuesVisible) DrawIndicatorTrendLine("h",Time[currentPeak],Time[lastPeak],values[currentPeak],values[lastPeak], divergenceBearishColor, STYLE_DOT);
   }
}

bool IsIndicatorPeak(double& values[], int i) { return(values[i] >= values[i+1] && values[i] > values[i+2] && values[i] > values[i-1]); }
bool IsIndicatorLow( double& values[], int i) { return(values[i] <= values[i+1] && values[i] < values[i+2] && values[i] < values[i-1]); }

int GetIndicatorLastPeak(double& values[], int shift){
   for(int i = shift+5; i<Bars; i++)
         if (values[i] >= values[i+1] && values[i] > values[i+2] && values[i] >= values[i-1] && values[i] > values[i-2]) return(i);
   return(-1);
}

int GetIndicatorLastLow(double& values[], int shift){
   for(int i = shift+5; i<Bars; i++)
         if (values[i] <= values[i+1] && values[i] < values[i+2] && values[i] <= values[i-1] && values[i] < values[i-2]) return(i);
   return(-1);
}

//+----------------------------------------------------------------------------------------------------------------------------------+
//|                                                                  
//+----------------------------------------------------------------------------------------------------------------------------------+

void DrawPriceTrendLine(string first,datetime t1, datetime t2, double p1, double p2, color lineColor, double style)
{
   string   label = divergenceUniqueID+first+"os"+DoubleToStr(t1,0);
   if (Interpolate) t2 += Period()*60-1;
    
   ObjectDelete(label);
      ObjectCreate(label, OBJ_TREND, 0, t1+Period()*60-1, p1, t2, p2, 0, 0);
         ObjectSet(label, OBJPROP_RAY, false);
         ObjectSet(label, OBJPROP_COLOR, lineColor);
         ObjectSet(label, OBJPROP_STYLE, style);
}

void DrawIndicatorTrendLine(string first,datetime t1, datetime t2, double p1, double p2, color lineColor, double style)
{
   int indicatorWindow = WindowFind(shortName);
   if (indicatorWindow < 0) return;
   if (Interpolate) t2 += Period()*60-1;
   
   string label = divergenceUniqueID+first+DoubleToStr(t1,0);
   ObjectDelete(label);
      ObjectCreate(label, OBJ_TREND, indicatorWindow, t1+Period()*60-1, p1, t2, p2, 0, 0);
         ObjectSet(label, OBJPROP_RAY, false);
         ObjectSet(label, OBJPROP_COLOR, lineColor);
         ObjectSet(label, OBJPROP_STYLE, style);
}

//+--------------------------------------------------------------------------------------+
//|   Arrow
//+--------------------------------------------------------------------------------------+
void manageArrow(int i){
   if (ShowArrows){
      deleteArrow(Time[i]);
      if (trend[i]!=trend[i+1]){
         if (ShowArrowsUp   && trend[i] == 1) drawArrow(i,arrowsUpColor,arrowsUpGap  ,233,false);
         if (ShowArrowsDown && trend[i] ==-1) drawArrow(i,arrowsDnColor,arrowsDownGap,234,true);
      }
   }
}               

void drawArrow(int i,color theColor, double theGap,int theCode,bool up){
   string name = arrowsIdentifier+":"+Time[i];
   double gap  = theGap*iATR(NULL,0,20,i);

   ObjectCreate(name,OBJ_ARROW,0,Time[i],0);
   ObjectSet(name,OBJPROP_ARROWCODE,theCode);
   ObjectSet(name,OBJPROP_COLOR,theColor);
   if (up)ObjectSet(name,OBJPROP_PRICE1,High[i]+gap);
   else  ObjectSet(name,OBJPROP_PRICE1,Low[i] -gap);
}

void deleteArrows(){
   string lookFor       = arrowsIdentifier+":";
   int    lookForLength = StringLen(lookFor);
   for (int i=ObjectsTotal()-1; i>=0; i--){
      string objectName = ObjectName(i);
      if (StringSubstr(objectName,0,lookForLength) == lookFor) ObjectDelete(objectName);
   }
}

void deleteArrow(datetime time){
   string lookFor = arrowsIdentifier+":"+time; ObjectDelete(lookFor);
}

//+------------------------------------------------------------------+
//|  Alerts
//+------------------------------------------------------------------+

void manageAlerts(){
   if (!calculateValue && alertsOn){
      if (alertsOnCurrent)int whichBar = 0;
      else     whichBar = 1; whichBar = iBarShift(NULL,0,iTime(NULL,timeFrame,whichBar));
      if (trend[whichBar] != trend[whichBar+1]){
         if (trend[whichBar] == 1) doAlert(whichBar,"up");
         if (trend[whichBar] ==-1) doAlert(whichBar,"down");
      }         
   }
}   

void doAlert(int forBar, string doWhat){
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   if(previousAlert != doWhat || previousTime != Time[forBar]) {
      previousAlert  = doWhat;
      previousTime   = Time[forBar];
      message =  StringConcatenate(Symbol()," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," dtosc trend changed to ",doWhat);
      if (alertsMessage) Alert(message);
      if (alertsEmail)   SendMail(StringConcatenate(Symbol(),"dtosc "),message);
      if (alertsSound)   PlaySound("enter now.wav");//PlaySound("alert2.wav");********************** Changed
   }
}

//+--------------------------------------------------------------------------------------------------------------------------+
//|   Smooth
//+--------------------------------------------------------------------------------------------------------------------------+

double wrk[][20];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

double iDSmooth(double price, double length, double phase, int i, int s=0){
   if (SmoothDouble)
         return (iSmooth(iSmooth(price,MathSqrt(length),phase,i,s),MathSqrt(length),phase,i,s+10));
   else  return (iSmooth(price,length,phase,i,s));
}

double iSmooth(double price, double length, double phase, int i, int s=0){
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   return(wrk[r][4+s]);
}


//+---------------------------------------------------------------------------------------------------------+
//| MTF
//+---------------------------------------------------------------------------------------------------------+

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

int stringToTimeFrame(string tfs){
   StringToUpper(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}

string timeFrameToString(int tf){
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}


//------------------------------------------------------------------
//  RSI,Wilders RSI, RSX,Cuttler RSI
//------------------------------------------------------------------

string rsiMethodNames[] = {"rsi","Wilders rsi","rsx","Cuttler RSI"};

string getRsiName(int& method){
   int max = ArraySize(rsiMethodNames)-1;
   method=MathMax(MathMin(method,max),0); return(rsiMethodNames[method]);
}

double workRsi[][13];
#define _price  0
#define _change 1
#define _changa 2

double iRsi(double price, double period, int i,int tRSI_Mode=0, int instanceNo=0){
   if (ArrayRange(workRsi,0)!=Bars) ArrayResize(workRsi,Bars);
   int z = instanceNo*13; 
   int r = Bars-i-1;
   workRsi[r][z+_price] = price;
   switch (tRSI_Mode){
      case 0: // RSI
         double alpha = 1.0/period; 
         if (r<period){
            int k; double sum = 0; for (k=0; k<period && (r-k-1)>=0; k++) sum += MathAbs(workRsi[r-k][z+_price]-workRsi[r-k-1][z+_price]);
            workRsi[r][z+_change] = (workRsi[r][z+_price]-workRsi[0][z+_price])/MathMax(k,1);
            workRsi[r][z+_changa] =                                         sum/MathMax(k,1);
         }
         else{
            double change = workRsi[r][z+_price]-workRsi[r-1][z+_price];
            workRsi[r][z+_change] = workRsi[r-1][z+_change] + alpha*(        change  - workRsi[r-1][z+_change]);
            workRsi[r][z+_changa] = workRsi[r-1][z+_changa] + alpha*(MathAbs(change) - workRsi[r-1][z+_changa]);
         }
         if (workRsi[r][z+_changa] != 0) return(50.0*(workRsi[r][z+_change]/workRsi[r][z+_changa]+1));
         else  return(50.0);

      case 1 :
         workRsi[r][z+1] = iSmma(0.5*(MathAbs(workRsi[r][z+_price]-workRsi[r-1][z+_price])+(workRsi[r][z+_price]-workRsi[r-1][z+_price])),0.5*(period-1),Bars-i-1,0);
         workRsi[r][z+2] = iSmma(0.5*(MathAbs(workRsi[r][z+_price]-workRsi[r-1][z+_price])-(workRsi[r][z+_price]-workRsi[r-1][z+_price])),0.5*(period-1),Bars-i-1,1);
         if((workRsi[r][z+1] + workRsi[r][z+2]) != 0) return(100.0 * workRsi[r][z+1]/(workRsi[r][z+1] + workRsi[r][z+2]));
         else  return(50);

      case 2 :     
         double Kg = (3.0)/(2.0+period), Hg = 1.0-Kg;
         if (r<period) { for (k=1; k<13; k++) workRsi[r][k+z] = 0; return(50); }  

         double mom = workRsi[r][_price+z]-workRsi[r-1][_price+z];
         double moa = MathAbs(mom);
         for (k=0; k<3; k++){
            int kk = k*2;
            workRsi[r][z+kk+1] = Kg*mom                + Hg*workRsi[r-1][z+kk+1];
            workRsi[r][z+kk+2] = Kg*workRsi[r][z+kk+1] + Hg*workRsi[r-1][z+kk+2]; mom = 1.5*workRsi[r][z+kk+1] - 0.5 * workRsi[r][z+kk+2];
            workRsi[r][z+kk+7] = Kg*moa                + Hg*workRsi[r-1][z+kk+7];
            workRsi[r][z+kk+8] = Kg*workRsi[r][z+kk+7] + Hg*workRsi[r-1][z+kk+8]; moa = 1.5*workRsi[r][z+kk+7] - 0.5 * workRsi[r][z+kk+8];
         }
         if (moa != 0)return(MathMax(MathMin((mom/moa+1.0)*50.0,100.00),0.00)); 
         else return(50);
      
      case 3 :
         double sump = 0;
         double sumn = 0;
         for (k=0; k<period; k++){
            double diff = workRsi[r-k][z+_price]-workRsi[r-k-1][z+_price];
               if (diff > 0) sump += diff;
               if (diff < 0) sumn -= diff;
         }
         if (sumn > 0)
               return(100.0-100.0/(1.0+sump/sumn));
         else  return(50);
   } 
   return(50);
}

double workSmma[][2];
double iSmma(double price, double period, int r, int instanceNo=0){
   if (ArrayRange(workSmma,0)!= Bars) ArrayResize(workSmma,Bars);
   if (r<period)workSmma[r][instanceNo] = price;
   else  workSmma[r][instanceNo] = workSmma[r-1][instanceNo]+(price-workSmma[r-1][instanceNo])/period;
   return(workSmma[r][instanceNo]);
}